[svn] gcry - r1158 - in trunk: . m4 src
svn author marcus
cvs at cvs.gnupg.org
Tue Jul 4 13:44:16 CEST 2006
Author: marcus
Date: 2006-07-04 13:44:01 +0200 (Tue, 04 Jul 2006)
New Revision: 1158
Added:
trunk/m4/onceonly.m4
trunk/m4/socklen.m4
trunk/m4/sys_socket_h.m4
Modified:
trunk/ChangeLog
trunk/configure.ac
trunk/m4/ChangeLog
trunk/src/ChangeLog
trunk/src/gcrypt.h
Log:
2006-07-04 Marcus Brinkmann <marcus at g10code.de>
* configure.ac: Call gl_TYPE_SOCKLEN_T instead of the other
socklen_t checks.
m4/
2006-07-04 Marcus Brinkmann <marcus at g10code.de>
* sys_socket_h.m4, socklen.m4, onceonly.m4: New files from gnulib.
src/
2006-07-04 Marcus Brinkmann <marcus at g10code.de>
* gcrypt.h [!HAVE_SYS_SOCKET_H]: Do not include sys/socket.h, but
the appropriate windows socket header.
Modified: trunk/ChangeLog
===================================================================
--- trunk/ChangeLog 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/ChangeLog 2006-07-04 11:44:01 UTC (rev 1158)
@@ -1,3 +1,8 @@
+2006-07-04 Marcus Brinkmann <marcus at g10code.de>
+
+ * configure.ac: Call gl_TYPE_SOCKLEN_T instead of the other
+ socklen_t checks.
+
2006-06-08 Marcus Brinkmann <marcus at g10code.de>
* configure.ac (PTH_LIBS): Add --all to pth-config invocation.
Modified: trunk/configure.ac
===================================================================
--- trunk/configure.ac 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/configure.ac 2006-07-04 11:44:01 UTC (rev 1158)
@@ -510,17 +510,8 @@
GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
-AC_CHECK_TYPE(socklen_t,,
- [AC_DEFINE_UNQUOTED([socklen_t],
- [int],
- [Define to `int' if unavailable.])],
- [
-#include <sys/types.h>
-#include <sys/socket.h>
- ])
+gl_TYPE_SOCKLEN_T
-TYPE_SOCKLEN_T
-
#######################################
#### Checks for library functions. ####
#######################################
Modified: trunk/m4/ChangeLog
===================================================================
--- trunk/m4/ChangeLog 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/m4/ChangeLog 2006-07-04 11:44:01 UTC (rev 1158)
@@ -1,3 +1,7 @@
+2006-07-04 Marcus Brinkmann <marcus at g10code.de>
+
+ * sys_socket_h.m4, socklen.m4, onceonly.m4: New files from gnulib.
+
2004-04-06 Werner Koch <wk at gnupg.org>
* libtool.m4: Updated from 1.5.4
Added: trunk/m4/onceonly.m4
===================================================================
--- trunk/m4/onceonly.m4 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/m4/onceonly.m4 2006-07-04 11:44:01 UTC (rev 1158)
@@ -0,0 +1,66 @@
+# onceonly.m4 serial 4 (gettext-0.15)
+dnl Copyright (C) 2002-2003, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl This file defines some "once only" variants of standard autoconf macros.
+dnl AC_CHECK_HEADERS_ONCE like AC_CHECK_HEADERS
+dnl AC_CHECK_FUNCS_ONCE like AC_CHECK_FUNCS
+dnl AC_CHECK_DECLS_ONCE like AC_CHECK_DECLS
+dnl AC_REQUIRE([AC_HEADER_STDC]) like AC_HEADER_STDC
+dnl The advantage is that the check for each of the headers/functions/decls
+dnl will be put only once into the 'configure' file. It keeps the size of
+dnl the 'configure' file down, and avoids redundant output when 'configure'
+dnl is run.
+dnl The drawback is that the checks cannot be conditionalized. If you write
+dnl if some_condition; then gl_CHECK_HEADERS(stdlib.h); fi
+dnl inside an AC_DEFUNed function, the gl_CHECK_HEADERS macro call expands to
+dnl empty, and the check will be inserted before the body of the AC_DEFUNed
+dnl function.
+
+dnl This file is only needed in autoconf <= 2.59. Newer versions of autoconf
+dnl have this macro built-in. But about AC_CHECK_DECLS_ONCE: note that in
+dnl autoconf >= 2.60 the symbol separator is a comma, whereas here it is
+dnl whitespace.
+
+dnl Autoconf version 2.57 or newer is recommended.
+AC_PREREQ(2.54)
+
+# AC_CHECK_HEADERS_ONCE(HEADER1 HEADER2 ...) is a once-only variant of
+# AC_CHECK_HEADERS(HEADER1 HEADER2 ...).
+AC_DEFUN([AC_CHECK_HEADERS_ONCE], [
+ :
+ AC_FOREACH([gl_HEADER_NAME], [$1], [
+ AC_DEFUN([gl_CHECK_HEADER_]m4_quote(translit(m4_defn([gl_HEADER_NAME]),
+ [-./], [___])), [
+ AC_CHECK_HEADERS(gl_HEADER_NAME)
+ ])
+ AC_REQUIRE([gl_CHECK_HEADER_]m4_quote(translit(gl_HEADER_NAME,
+ [-./], [___])))
+ ])
+])
+
+# AC_CHECK_FUNCS_ONCE(FUNC1 FUNC2 ...) is a once-only variant of
+# AC_CHECK_FUNCS(FUNC1 FUNC2 ...).
+AC_DEFUN([AC_CHECK_FUNCS_ONCE], [
+ :
+ AC_FOREACH([gl_FUNC_NAME], [$1], [
+ AC_DEFUN([gl_CHECK_FUNC_]m4_defn([gl_FUNC_NAME]), [
+ AC_CHECK_FUNCS(m4_defn([gl_FUNC_NAME]))
+ ])
+ AC_REQUIRE([gl_CHECK_FUNC_]m4_defn([gl_FUNC_NAME]))
+ ])
+])
+
+# AC_CHECK_DECLS_ONCE(DECL1 DECL2 ...) is a once-only variant of
+# AC_CHECK_DECLS(DECL1, DECL2, ...).
+AC_DEFUN([AC_CHECK_DECLS_ONCE], [
+ :
+ AC_FOREACH([gl_DECL_NAME], [$1], [
+ AC_DEFUN([gl_CHECK_DECL_]m4_defn([gl_DECL_NAME]), [
+ AC_CHECK_DECLS(m4_defn([gl_DECL_NAME]))
+ ])
+ AC_REQUIRE([gl_CHECK_DECL_]m4_defn([gl_DECL_NAME]))
+ ])
+])
Added: trunk/m4/socklen.m4
===================================================================
--- trunk/m4/socklen.m4 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/m4/socklen.m4 2006-07-04 11:44:01 UTC (rev 1158)
@@ -0,0 +1,52 @@
+# socklen.m4 serial 4
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Albert Chin, Windows fixes from Simon Josefsson.
+
+dnl Check for socklen_t: historically on BSD it is an int, and in
+dnl POSIX 1g it is a type of its own, but some platforms use different
+dnl types for the argument to getsockopt, getpeername, etc. So we
+dnl have to test to find something that will work.
+
+dnl On mingw32, socklen_t is in ws2tcpip.h ('int'), so we try to find
+dnl it there first. That file is included by gnulib's socket_.h, which
+dnl all users of this module should include. Cygwin must not include
+dnl ws2tcpip.h.
+AC_DEFUN([gl_TYPE_SOCKLEN_T],
+ [AC_REQUIRE([gl_HEADER_SYS_SOCKET])dnl
+ AC_CHECK_TYPE([socklen_t], ,
+ [AC_MSG_CHECKING([for socklen_t equivalent])
+ AC_CACHE_VAL([gl_cv_gl_cv_socklen_t_equiv],
+ [# Systems have either "struct sockaddr *" or
+ # "void *" as the second argument to getpeername
+ gl_cv_socklen_t_equiv=
+ for arg2 in "struct sockaddr" void; do
+ for t in int size_t "unsigned int" "long int" "unsigned long int"; do
+ AC_TRY_COMPILE(
+ [#include <sys/types.h>
+ #include <sys/socket.h>
+
+ int getpeername (int, $arg2 *, $t *);],
+ [$t len;
+ getpeername (0, 0, &len);],
+ [gl_cv_socklen_t_equiv="$t"])
+ test "$gl_cv_socklen_t_equiv" != "" && break
+ done
+ test "$gl_cv_socklen_t_equiv" != "" && break
+ done
+ ])
+ if test "$gl_cv_socklen_t_equiv" = ""; then
+ AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
+ fi
+ AC_MSG_RESULT([$gl_cv_socklen_t_equiv])
+ AC_DEFINE_UNQUOTED([socklen_t], [$gl_cv_socklen_t_equiv],
+ [type to use in place of socklen_t if not defined])],
+ [#include <sys/types.h>
+ #if HAVE_SYS_SOCKET_H
+ # include <sys/socket.h>
+ #elif HAVE_WS2TCPIP_H
+ # include <ws2tcpip.h>
+ #endif])])
Added: trunk/m4/sys_socket_h.m4
===================================================================
--- trunk/m4/sys_socket_h.m4 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/m4/sys_socket_h.m4 2006-07-04 11:44:01 UTC (rev 1158)
@@ -0,0 +1,23 @@
+# sys_socket_h.m4 serial 2
+dnl Copyright (C) 2005, 2006 Free Software Foundation, Inc.
+dnl This file is free software; the Free Software Foundation
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl From Simon Josefsson.
+
+AC_DEFUN([gl_HEADER_SYS_SOCKET],
+[
+ AC_CHECK_HEADERS_ONCE([sys/socket.h])
+ if test $ac_cv_header_sys_socket_h = yes; then
+ SYS_SOCKET_H=''
+ else
+ dnl We cannot use AC_CHECK_HEADERS_ONCE here, because that would make
+ dnl the check for those headers unconditional; yet cygwin reports
+ dnl that the headers are present but cannot be compiled (since on
+ dnl cygwin, all socket information should come from sys/socket.h).
+ AC_CHECK_HEADERS([winsock2.h ws2tcpip.h])
+ SYS_SOCKET_H='sys/socket.h'
+ fi
+ AC_SUBST(SYS_SOCKET_H)
+])
Modified: trunk/src/ChangeLog
===================================================================
--- trunk/src/ChangeLog 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/src/ChangeLog 2006-07-04 11:44:01 UTC (rev 1158)
@@ -1,3 +1,8 @@
+2006-07-04 Marcus Brinkmann <marcus at g10code.de>
+
+ * gcrypt.h [!HAVE_SYS_SOCKET_H]: Do not include sys/socket.h, but
+ the appropriate windows socket header.
+
2006-06-21 Werner Koch <wk at g10code.com>
* global.c (gcry_xcalloc, gcry_xcalloc_secure): Made safe against
Modified: trunk/src/gcrypt.h
===================================================================
--- trunk/src/gcrypt.h 2006-06-21 09:19:13 UTC (rev 1157)
+++ trunk/src/gcrypt.h 2006-07-04 11:44:01 UTC (rev 1158)
@@ -28,7 +28,18 @@
#include <gpg-error.h>
#include <sys/types.h>
+
+#if HAVE_SYS_SOCKET_H
#include <sys/socket.h>
+#else
+#if HAVE_WINSOCK2_H
+# include <winsock2.h>
+#endif
+#if HAVE_WS2TCPIP_H
+# include <ws2tcpip.h>
+#endif
+#endif
+
#include <sys/time.h>
/* This is required for error code compatibility. */
More information about the Gnupg-commits
mailing list