[PATCH] Add some AC_HELP_STRING macros to configure.ac

[Art Haas]

Hi.

Here's a small patch adding a couple of AC_HELP_STRING macros to the
configure.ac file, and also a trivial change of AM_CONFIG_HEADER to
AC_CONFIG_HEADER.

Builds of the current CVS code have worked and passed the test suite.
I'm building on i586-pc-linux-gnu (Debian Unstable), using the gcc-3.4
and gcc-4.0 packages.

My thanks to everyone working on gnupg.

Art Haas

Index: configure.ac
===================================================================
RCS file: /cvs/gnupg/gnupg/configure.ac,v
retrieving revision 1.143
diff -u -r1.143 configure.ac
--- configure.ac	31 May 2005 12:26:02 -0000	1.143
+++ configure.ac	13 Jun 2005 19:31:50 -0000
@@ -36,7 +36,7 @@
 AC_CONFIG_SRCDIR(g10/g10.c)
 AC_CANONICAL_HOST
 AM_INIT_AUTOMAKE([std-options])
-AM_CONFIG_HEADER(config.h)
+AC_CONFIG_HEADER(config.h)
 
 AC_GNU_SOURCE
 
@@ -45,8 +45,9 @@
 dnl
 AC_MSG_CHECKING([which random module to use])
 AC_ARG_ENABLE(static-rnd,
-    [  --enable-static-rnd=[egd|unix|linux|auto]  ],
-[use_static_rnd=$enableval], [use_static_rnd=default] )
+              AC_HELP_STRING([--enable-static-rnd=@<:@egd|unix|linux|auto@:>@],
+	                     [enable static random number generator]),
+              [use_static_rnd=$enableval], [use_static_rnd=default])
 
 if test "$use_static_rnd" = no; then
     use_static_rnd=default
@@ -66,8 +67,9 @@
 esac
 
 AC_ARG_WITH(egd-socket,
-    [  --with-egd-socket=NAME  use NAME for the EGD socket],
-            egd_socket_name="$withval", egd_socket_name="" )
+            AC_HELP_STRING([--with-egd-socket=NAME],
+                           [use NAME for the EGD socket]),
+            [egd_socket_name="$withval"], [egd_socket_name=""])
 AC_DEFINE_UNQUOTED(EGD_SOCKET_NAME, "$egd_socket_name",
                    [Define if you don't want the default EGD socket name.
                     For details see cipher/rndegd.c])
@@ -89,14 +91,16 @@
 
 AC_MSG_CHECKING([whether assembler modules are requested])
 AC_ARG_ENABLE(asm,
-[  --disable-asm           do not use assembler modules],
-     try_asm_modules=$enableval, try_asm_modules=yes)
+              AC_HELP_STRING([--disable-asm],
+                             [do not use assembler modules]),
+              try_asm_modules=$enableval, try_asm_modules=yes)
 AC_MSG_RESULT($try_asm_modules)
 
 AC_MSG_CHECKING([whether memory guard is requested])
 AC_ARG_ENABLE(m-guard,
-    [  --enable-m-guard        enable memory guard facility],
-    use_m_guard=$enableval, use_m_guard=no)
+              AC_HELP_STRING([--enable-m-guard],
+                             [enable memory guard facility]),
+              [use_m_guard=$enableval], [use_m_guard=no])
 AC_MSG_RESULT($use_m_guard)
 if test "$use_m_guard" = yes ; then
     AC_DEFINE(M_GUARD,1,[Define to use the (obsolete) malloc guarding feature])
@@ -304,7 +308,8 @@
   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
     AC_ARG_WITH(photo-viewer,
-        [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
+        AC_HELP_STRING([--with-photo-viewer=FIXED_VIEWER],
+                       [set a fixed photo ID viewer]),
         [if test "$withval" = yes ; then
            withval=no
         elif test "$withval" != no ; then
@@ -378,8 +383,9 @@
 
 AC_MSG_CHECKING([whether the included zlib is requested])
 AC_ARG_WITH(included-zlib,
-    [  --with-included-zlib    use the zlib code included here],
-[g10_force_zlib="$withval"], [g10_force_zlib=no] )
+            AC_HELP_STRING([--with-included-zlib],
+                           [use the zlib code included here]),
+            [g10_force_zlib="$withval"], [g10_force_zlib=no])
 AC_MSG_RESULT($g10_force_zlib)
 
 dnl
@@ -412,8 +418,9 @@
 dnl
 AC_MSG_CHECKING([whether use of capabilities is requested])
 AC_ARG_WITH(capabilities,
-    [  --with-capabilities     use linux capabilities [default=no]],
-[use_capabilities="$withval"],[use_capabilities=no])
+            AC_HELP_STRING([--with-capabilities],
+                           [use linux capabilities @<:@default=no@:>@]),
+            [use_capabilities="$withval"], [use_capabilities=no])
 AC_MSG_RESULT($use_capabilities)
 
 # To avoid double inclusion of config.h which might happen at some
-- 
Man once surrendering his reason, has no remaining guard against absurdities
the most monstrous, and like a ship without rudder, is the sport of every wind.

-Thomas Jefferson to James Smith, 1822