gpg Real Name part.

[Norbert Bollow]

> > If + is a valid character in a mailbox name, it should be allowed.
> > Anyone has the RFC handy?

It's perfectly valid character, and it's in very common usage, hence
it should be allowed. BTW, according to RFC821 and RFC822 any of the
128 ASCII characters can occur in the local part of an e-mail address
if quoted properly, although I've _never_ seen an e-mail address
containing control characters (such a thing would be outright silly,
even though perfectly legal - I'm sure you can break a lot of e-mail
software by using an e-mail address which contains backslash-NUL).
Another note: Even though 8-bit-characters are illegal, they _do_
occur in e-mail addresses.

> Yes it's valid.  One MTA in fact (qmail) uses + and - characters to
> designate alternate delivery mailboxes.

Actually it is sendmail (and compatibles) which uses '+' for this.
qmail uses '-'.

Greetings, Norbert.

P.S. Here's the quote from RFC821. The specification in RFC822 goes
along similar lines.


            <domain> ::=  <element> | <element> "." <domain>

            <element> ::= <name> | "#" <number> | "[" <dotnum> "]"

            <mailbox> ::= <local-part> "@" <domain>

            <local-part> ::= <dot-string> | <quoted-string>

            <name> ::= <a> <ldh-str> <let-dig>

            <ldh-str> ::= <let-dig-hyp> | <let-dig-hyp> <ldh-str>

            <let-dig> ::= <a> | <d>

            <let-dig-hyp> ::= <a> | <d> | "-"

            <dot-string> ::= <string> | <string> "." <dot-string>

            <string> ::= <char> | <char> <string>

            <quoted-string> ::=  """ <qtext> """

            <qtext> ::=  "\" <x> | "\" <x> <qtext> | <q> | <q> <qtext>

            <char> ::= <c> | "\" <x>

            <dotnum> ::= <snum> "." <snum> "." <snum> "." <snum>

            <number> ::= <d> | <d> <number>

            <CRLF> ::= <CR> <LF>

            <CR> ::= the carriage return character (ASCII code 13)

            <LF> ::= the line feed character (ASCII code 10)

            <SP> ::= the space character (ASCII code 32)

            <snum> ::= one, two, or three digits representing a decimal
                      integer value in the range 0 through 255

            <a> ::= any one of the 52 alphabetic characters A through Z
                      in upper case and a through z in lower case

            <c> ::= any one of the 128 ASCII characters, but not any
                      <special> or <SP>

            <d> ::= any one of the ten digits 0 through 9

            <q> ::= any one of the 128 ASCII characters except <CR>,
                      <LF>, quote ("), or backslash (\)

            <x> ::= any one of the 128 ASCII characters (no exceptions)

            <special> ::= "<" | ">" | "(" | ")" | "[" | "]" | "\" | "."
                      | "," | ";" | ":" | "@"  """ | the control
                      characters (ASCII codes 0 through 31 inclusive and
                      127)

         Note that the backslash, "\", is a quote character, which is
         used to indicate that the next character is to be used
         literally (instead of its normal interpretation).  For example,
         "Joe\,Smith" could be used to indicate a single nine character
         user field with comma being the fourth character of the field.