Config.status on OS X

[Paul Eggert]

> From: Werner Koch <wk@gnupg.org>
> Date: 20 Jun 2001 18:47:38 +0200
> 
> BTW, the LFS configuration stuff is by Paul Eggert and he told me that
> it is just a temporary solution until the stuff comes with a new
> autoconf version.

It's in autoconf 2.50.  Once you switch to autoconf 2.50, you should
be able to replace almost all the stuff I sent you with a simple
invocation AC_SYS_LARGEFILE.  autoconf 2.50 defines AC_SYS_LARGEFILE
properly.

One other thing: you need to invoke AC_FUNC_FSEEKO instead of
AC_CHECK_FUNCS(fseeko), as fseeko was broken out of AC_SYS_LARGEFILE
in autoconf 2.50.

Here's a patch, relative to GnuPG 1.0.6.

2001-06-20  Paul Eggert  <eggert@twinsun.com>

	* configure.in (AC_PREREQ): Require autoconf 2.50.
	(AC_FUNC_FSEEKO): Add.
	(AC_CHECK_FUNCS): Remove fseeko.
	* acinclude.m4 (AC_SYS_LARGEFILE): Remove; supplied by autoconf 2.50.

--- gnupg-1.0.6/configure.in	Mon May 28 05:46:13 2001
+++ gnupg-fixed/configure.in	Wed Jun 20 13:09:52 2001
@@ -23,7 +23,7 @@
 dnl Must reset CDPATH so that bash's cd does not print to stdout
 CDPATH=
 
-AC_PREREQ(2.13)
+AC_PREREQ(2.50)
 AC_INIT(g10/g10.c)
 AC_CONFIG_AUX_DIR(scripts)
 AM_CONFIG_HEADER(config.h)
@@ -426,11 +426,12 @@
 
 
 dnl Checks for library functions.
+AC_FUNC_FSEEKO
 AC_FUNC_VPRINTF
 AC_CHECK_FUNCS(strerror stpcpy strlwr stricmp tcgetattr rand strtoul mmap)
 AC_CHECK_FUNCS(memmove gettimeofday getrusage gethrtime setrlimit clock_gettime)
 AC_CHECK_FUNCS(memicmp atexit raise getpagesize strftime nl_langinfo)
-AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask fseeko)
+AC_CHECK_FUNCS(waitpid wait4 sigaction sigprocmask)
 
 GNUPG_CHECK_MLOCK
 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
--- gnupg-1.0.6/acinclude.m4	Fri Apr 27 07:42:25 2001
+++ gnupg-fixed/acinclude.m4	Wed Jun 20 12:59:29 2001
@@ -751,83 +751,3 @@
   AC_DEFINE(MKDIR_TAKES_ONE_ARG)
 fi
 ])
-
- 
-dnl AC_SYS_LARGEFILE is stolen from tar.
-dnl This can be removed once the official successor to autoconf 2.13 is out.
-#serial 12
-
-dnl By default, many hosts won't let programs access large files;
-dnl one must use special compiler options to get large-file access to work.
-dnl For more details about this brain damage please see:
-dnl http://www.sas.com/standards/large.file/x_open.20Mar96.html
-
-dnl Written by Paul Eggert <eggert@twinsun.com>.
-
-dnl Internal subroutine of AC_SYS_LARGEFILE.
-dnl AC_SYS_LARGEFILE_TEST_INCLUDES
-AC_DEFUN(AC_SYS_LARGEFILE_TEST_INCLUDES,
-  [[#include <sys/types.h>
-    int a[(off_t) 9223372036854775807 == 9223372036854775807 ? 1 : -1];
-  ]])
-
-dnl Internal subroutine of AC_SYS_LARGEFILE.
-dnl AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE, CACHE-VAR,
-dnl                              COMMENT, INCLUDES,FUNCTION-BODY)
-AC_DEFUN(AC_SYS_LARGEFILE_MACRO_VALUE,
-  [AC_CACHE_CHECK([for $1 value needed for large files], $3,
-     [$3=no
-      AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES
-$5
-        ,
-       [$6],
-       ,
-       [AC_TRY_COMPILE([#define $1 $2]
-AC_SYS_LARGEFILE_TEST_INCLUDES
-$5
-          ,
-          [$6],
-          [$3=$2])])])
-   if test "[$]$3" != no; then
-     AC_DEFINE_UNQUOTED([$1], [$]$3, [$4])
-   fi])
-
-AC_DEFUN(AC_SYS_LARGEFILE,
-  [AC_ARG_ENABLE(largefile,
-     [  --disable-largefile     omit support for large files])
-   if test "$enable_largefile" != no; then
-
-     AC_CACHE_CHECK([for special C compiler options needed for large files],
-       ac_cv_sys_largefile_CC,
-       [ac_cv_sys_largefile_CC=no
-        if test "$GCC" != yes; then
-         # IRIX 6.2 and later do not support large files by default,
-         # so use the C compiler's -n32 option if that helps.
-         AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, , ,
-           [ac_save_CC="$CC"
-            CC="$CC -n32"
-            AC_TRY_COMPILE(AC_SYS_LARGEFILE_TEST_INCLUDES, ,
-              ac_cv_sys_largefile_CC=' -n32')
-            CC="$ac_save_CC"])
-        fi])
-     if test "$ac_cv_sys_largefile_CC" != no; then
-       CC="$CC$ac_cv_sys_largefile_CC"
-     fi
-
-     AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
-       ac_cv_sys_file_offset_bits,
-       [Number of bits in a file offset, on hosts where this is settable.])
-     AC_SYS_LARGEFILE_MACRO_VALUE(_LARGEFILE_SOURCE, 1,
-       ac_cv_sys_largefile_source,
-       [Define to make ftello visible on some hosts (e.g. HP-UX 10.20).],
-       [#include <stdio.h>], [return !ftello;])
-     AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
-       ac_cv_sys_large_files,
-       [Define for large files, on AIX-style hosts.])
-     AC_SYS_LARGEFILE_MACRO_VALUE(_XOPEN_SOURCE, 500,
-       ac_cv_sys_xopen_source,
-       [Define to make ftello visible on some hosts (e.g. glibc 2.1.3).],
-       [#include <stdio.h>], [return !ftello;])
-   fi
-  ])
-